Code: ASM Resource Thread

[Psyinide]

Hmm, I've been asked to do this before and it's quite the common request. However, it's so easy and straight forward, I'm always left wondering why people don't do it themselves. Then I remember, even if it's easy for me, I guess it's not as easy if you don't know what to do :P

Trainer Capture toggle by Pokeball

What this does right now, if check if the thrown Pokeball is a masterball. If it is, allow capture. If it's not a masterball then the normal "trainer has blocked the ball" will occur. To change which ball toggles the capture look at my comments in the code and change 0x1 - masterball to something else of your choice.

Spoiler:

Taken from XSE:
#define ITEM_MASTERBALL 0x1
#define ITEM_ULTRABALL 0x2
#define ITEM_GREATBALL 0x3
#define ITEM_POKEBALL 0x4
#define ITEM_SAFARIBALL 0x5
#define ITEM_NETBALL 0x6
#define ITEM_DIVEBALL 0x7
#define ITEM_NESTBALL 0x8
#define ITEM_REPEATBALL 0x9
#define ITEM_TIMERBALL 0xA
#define ITEM_LUXURYBALL 0xB
#define ITEM_PREMIERBALL 0xC

How to insert:
Compile and insert the following routine into freespace:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	ldr r0, .Ball
	ldrb r0, [r0]
	cmp r0, #0x1 @masterball
	beq capture
	mov r0, #0x0
	mov r1, #0x5
	ldr r3, =(0x800E194 +1)
	bl linker
	ldr r0, =(0x802D4A0 +1)
	bx r0

capture:
	ldr r0, =(0x802D4B4 +1)
	bx r0

linker:
	bx r3
	
.align 2

.Ball:
	.word 0x2023D68

Here is a compiled version:

06 48 00 78 01 28 06 D0 00 20 05 21 04 4B 00 F0 04 F8 04 48 00 47 04 48 00 47 18 47 68 3D 02 02 95 E1 00 08 A1 D4 02 08 B5 D4 02 08

Now navigate to 0x2D498 and insert the following:

 00 48 00 47 XX XX XX 08

Where XX XX XX is the reverse hex pointer +1 of where you inserted the routine.

Usage:
No usage! It's all done with the power of ASMAGIX!

Works great. I've set my script up to also check flag 0x203, if it's set stealing is disabled. I found that I need this ability because capturing a trainer's Pokemon ends the trainer battle immediately. This is my first ASM attempt, apologizes if I made any mistakes. The code works properly in my testing.

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r1-r3}
	ldr r0, .Ball
	ldrb r0, [r0]
	cmp r0, #0x1 @masterball
	beq checkflag
	b nocap

checkflag:
    mov r0, #0xFF
    lsl r0, r0, #0x1
    add r0, r0, #0x5
    ldr r3, =(0x806E6D0 +1)
    bl linker
    cmp r0, #0x0
    beq capture

nocap:
	pop {r1-r3}
	mov r0, #0x0
	mov r1, #0x5
	ldr r3, =(0x800E194 +1)
	bl linker
	ldr r0, =(0x802D4A0 +1)
	bx r0

capture:
	pop {r1-r3}
	ldr r0, =(0x802D4B4 +1)
	bx r0

linker:
	bx r3
	
.align 2

.Ball:
	.word 0x2023D68

Compiled version below. Swap out the XX with the Pokeball item number, 01 for a Masterball.

Spoiler:

0eb4 0c48 0078 XX28 00d0 07e0 ff20 4000
0530 094b 00f0 0df8 0028 07d0 0ebc 0020
0521 064b 00f0 05f8 0548 0047 0ebc 0548
0047 1847 683d 0202 d1e6 0608 95e1 0008
a1d4 0208 b5d4 0208

 

[Lance32497]

Yes, I also don't know how to use a party slot as a parameter by a scripter as we always don't know what's the player's pokemon. Special 0x9F is a pokemon selection screen, but who knows what the player will do? If I use it, i must decrypt its species as well.

The reason, for me, why Party slot number and not species index number, is to work well with Special 0x9F. What if the hacker wants to evolve a charmander on the third slot, and not the first slot? It would be very useful, and about specie decryption, JPAN has a routine (don't get it wrong) that decrypts pokemon, identifying specie index number is not a hard way to do via scripting, cuz JPAN has that routine.

 

[jiangzhengwenjzw]

The reason, for me, why Party slot number and not species index number, is to work well with Special 0x9F. What if the hacker wants to evolve a charmander on the third slot, and not the first slot? It would be very useful, and about specie decryption, JPAN has a routine (don't get it wrong) that decrypts pokemon, identifying specie index number is not a hard way to do via scripting, cuz JPAN has that routine.

I don't use JPAN's engine so I don't know what his engine includes though.
My routine will evolve the first pokemon of a specified species in your team. For example, I search for ho-oh in the player's team and get that it's in the second slot, then the routine will evolve it. Therefore it can achieve the goal.
If you insist that choosing a pokemon and then checking if the selected pokemon is of specified species, you can ask someone else to enhance it as it's very very simple. For me, I think it's not bad so I don't want to touch the routines again.

 

[GoGoJJTech]

Are you guys really unaware of the Pokémon decryption routines already in the games?

 

[Lance32497]

Are you guys really unaware of the Pokémon decryption routines already in the games?

yup, is there any? Tell us please

 

[Joexv]

yup, is there any? Tell us please

Go look through basically any routine on this website that deals with Pokemon. Besides if this is so easy to do why don't you do it yourself? What you're asking for is indeed easy to accomplish, but I'm fairly certain that just using the Selector Special then running another routine(that's already made mind you) to check the species.

 

[BLAx501!]

Instant NPC sprite switch

This is related to the last hack, but can be more useful for a less permanent change. It can also work on other NPCs. Callasm as usual with the NPC person number in 0x8000 (same ID you use with applymovement - and 0xFF for the player) and the target sprite (the sprite index you'd use in advance map) in 0x8001.

Code untested.

Spoiler:

	.align 2
	.thumb

instant_npc_frame_switch:
	push {r4-r6, lr}
	sub sp, #4
	
	ldr r4, variables

	@@ Determine npc state id from person id	
	ldr r0, saveblock1_mapdata
	ldr r0, [r0]
	ldrb r0, [r4]		@ person/local ID from var 0x8000
	ldrb r1, [r0, #5] 	@ current map
	ldrb r2, [r0, #4]	@ current bank
	mov r3, sp
	ldr r5, npc_id_by_local_id_and_map_ret_success
	bl call_via_r5
	cmp r0, #0 		@ failure check
	bne instant_npc_frame_switch_return

	@@ Get npc_state
	mov r0, sp
	ldrb r1, [r0] 		@ npc_id
	lsl r0, r1, #3		@ npc_states + 0x24 * npc_id
	add r0, r1
	lsl r0, #2
	ldr r1, npc_states
	add r6, r0, r1

	@@ Change Sprite
	mov r0, r6 		@ npc_state
	ldrb r1, [r4, #2]	@ sprite index from var 0x8001
	ldr r5, npc_change_sprite
	bl call_via_r5

	@@ Update direction to prevent graphical artifacts
	mov r0, r6
	ldrb r1, [r0, #0x18]	@ npc direction
	lsr r1, #4
	ldr r5, npc_turn
	bl npc_turn
	
instant_npc_frame_switch_return:	
	add sp, #4
	pop {r4-r6, pc}

call_via_r5:
	bx r5

	.align 2
variables: .word 0x020370B8 	@ script var 0x8000
saveblock1_mapdata: .word 0x03005008
npc_states: .word 0x02036E38	
npc_change_sprite: .word 0x081507BC + 1
npc_turn: .word 0x0805F218 + 1
npc_id_by_local_id_and_map_ret_success:	.word 0x0805DF84 + 1

It would be cool if someone could test these and write example scripts. I am too lazy.

Hmm, I've tried it, but it gives me this error on VBA-M

And freezes the game. Any ideas??

EDIT: Simple test script to change Players OW

#dynamic 0x800000
#org @start
setvar 0x8000 0xFF
setvar 0x8001 0x18
callasm 0x8800001
end

EDIT2: The error above happens when trying to change the player OW as I said. When trying to change a NPC it just does nothing but doesn't freezes.

 

[azurile13]

Hmm, I've tried it, but it gives me this error on VBA-M

And freezes the game. Any ideas??

EDIT: Simple test script to change Players OW

#dynamic 0x800000
#org @start
setvar 0x8000 0xFF
setvar 0x8001 0x18
callasm 0x8800001
end

EDIT2: The error above happens when trying to change the player OW as I said. When trying to change a NPC it just does nothing but doesn't freezes.

Don't know what specifically the problem is, but I do immediately notice at least one:

ldr r5, npc_turn
bl npc_turn

instead of

ldr r5, npc_turn
bl call_via_r5

 

[BLAx501!]

Don't know what specifically the problem is, but I do immediately notice at least one:

ldr r5, npc_turn
bl npc_turn

instead of

ldr r5, npc_turn
bl call_via_r5

Yup, you were right :D

I can now change player's OW, but NPC doesn't seem to work :/

Should Touched or Spherical Ice edit that post to add this little change??

 

[azurile13]

Yup, you were right :D

I can now change player's OW, but NPC doesn't seem to work :/

Should Touched or Spherical Ice edit that post to add this little change??

https://imgur.com/a/nKQXA
Sad times.

To be honest tho - although it would be nice to have that fixed, if mods had to fix every error in every post on this site, their workload would never end :D

 

[garrett]

Hey, are there any tutorials on-site where I can learn how to ASM?

 

[Substitute Doll]

Hey, are there any tutorials on-site where I can learn how to ASM?

Here: https://www.pokecommunity.com/showthread.php?t=343871

 

[Starfall321]

I found that how frustration when playing some Emerald hack with bad egg/event corruption caused by usage of unsafe flag/var.
IDK if anyone had already port Jambo's routine to Emerald because I can't find any relevant post ATM.

Emerald safe variables hack

Spoiler:

@Goto 0x9d650, change the code here to 00 48 00 47 [asm location +1 reverse pointer]
@Goto 0x9D664, change the bytes here to 00 00
@Usable range :0x4000-0x40FF,0x5000-0x51FF,0x8000 - 0x8016
@credit to Jambo51 for his awesome routine for Fire Red.
.align 2

VAR4000_40FF:
mov r0, #0x40
lsl r0, r0, #0x8
cmp r1, r0
blt exit

mov r0, #0x41
lsl r0, r0, #0x8
cmp r1, r0
blt normal

VAR5000_5200:
mov r0, #0x50
lsl r0, r0, #0x8
cmp r1, r0
blt exit

lsl r0, r1, #0x10
cmp r0, #0x0
blt alt

mov r0, #0x52
lsl r0, r0, #0x8
cmp r1, r0
bge exit

MEMORY_LOCATION:
mov r0, #0x50
lsl r0, r0, #0x8
sub r1, r1, r0
lsl r1, r1, #0x1
ldr r0, =0x0203db00 @save block location, 1 var cost 2 bytes so you will need 0x400 bytes here.
add r0, r0, r1


exit2: pop {r1}
bx r1

exit: mov r0, #0x0
b exit2

normal: ldr r0, =0x0809D67C+1
bx r0
alt: ldr r0, =0x0809D664+1
bx r0

Emerald safe flag hack

Spoiler:

@Goto 0x9d702, change the code here to, 0000 0048 0047 [asm location +1 reverse pointer]
@Credit to Jambo51 for original routine
@Not sure how flags >0x1900 working, technically it should not work but I never do massive test.
@In case you want to be safe, just never set a flag >0x1900.
@New safe flag range :0x900-0x18FF, you can still using 0x0-0x900 range.

.align 2
FLAG900_1900:
mov r0, #0x9
lsl r0, r0, #0x8
cmp r2, r0
blt normal
mov r0, #0x19
lsl r0, r0, #0x8
cmp r2, r0
bge noget

mov r0, #0x9
lsl r0, r0, #0x8
sub r2, r2, r0
lsr r1, r2, #3
ldr r0, =0x0203df00 @save block location, a total of 0x1000 flags cost 0x200 bytes here
exit: add r0, r0, r1
pop {r1}
bx r1

normal: ldr r0, =0x03005d8c
ldr r0, [r0, #0]

there: lsr r1, r1, #0x13
ldr r2, =0x1270
add r1, r1, r2
b exit

noget: add r0, r2, #0x0
b there

Pls tell me if any bug found.

 

[GoGoJJTech]

<deleted post>

Someone offered to pay for it (and then I'd release it) but they never paid and I never learned how to use Github. Tough world :(
Hey, I have an idea!
You can do it!

 

[Joexv]

<deleted post>

Woah when did I become a veteran???

Edit: Also if we're so unhelpful then how did I get a helping hand emblem?

 

[Blah]

<deleted post>

Nah, Spherical Ice isn't that kind of person. I had received the emblem from him long before interacting with him.

It seems like this daily dose of drama stems from the response to where/how to use the encryption functions in the game. Like Joexv and GoGo had pointed out, there is a built-in Pokemon decrypter/encrypter function which you can use to retrieve and set certain aspects of a Pokemon. Since they failed to site any sources or further readings, you can check the documentation here out: https://www.romhack.me/database/23/fire-red-commonly-used-asm-rom-offsets/

The first two are the ones that Lance and friends are interested in. If you're looking for applications of these functions, there are many inside this very thread. Just take a look at the first post and choose a routine dealing with Pokemon, which you'd like to inspect. Finally, if further problems arise, the ASM help thread is in the beginner's lounge.

Please guys, lets not be so hateful to eachother. Also gogo's not a veteran, she's a nab :^)

 

[pokefreak890]

Thanks GOGOJJTECH for crediting me ;) but you didn't have to put it that way but it's fine we are all cool here at the end of the day :)

 

[i0Bjhansen0]

I know the ability thread is for existing abilities so I'm posting this here. I want to make new abilities that are similar to Torrent, Blaze, Overgrow, and Swarm, that use other types, mainly ones I've made. Now, I don't know ASM, and don't have a clue where to start.

But could someone please... (for Fire Red)
1. Provide an offset to change to hook a new routine off of to make a new ability.
2. Provide something similar to the original "power up" ability that has notes to what can be changed.
3. And provide a bit of code to allow the routine to return to the original routine.

So, for instance.

Spoiler:

this may not even be remotely close to actual asm. just me trying to be less obscure.
[Start routine]
(code needed to start)
insert XX XX XX (As many times necessary) YY(+1 if necessary) YY YY (offset) XX XX at 0xXXXXXX

.main
check health
if <33% goto .abilitycheck
if not goto .return

.abilitycheck
check ability
if Torrent goto .powerupwater
if Blaze goto .powerupfire
if Overgrow goto .powerupgrass
if Swarm goto .powerupbug
if (new ability) goto .powerup(new type)
if not goto .return

.powerupwater
check movetype
if notwater goto .return
increase power
goto .return

.powerupfire
checkmovetype
if notfire goto .return
increase power
goto .return

.powerupgrass
checkmovetype
if notgrass goto .return
increase power
goto .return

.powerupbug
checkmovetype
if notbug goto .return
increase power
goto .return

.powerup(new type)
checkmovetype
if not(new type) goto .return
increase power
goto .return

.return
(code to return back to the original routine)

(any other remaining code to tie up loose ends or whatnot)

Hopefully someone with the knowledge can understand what I typed. This is ability stuff but the ability resource thread is for gen 4-6 abilities, not custom ones. But this is ASM so here it is.

 

[Le pug]

Spoiler:

I think he wants to set a default name while skipping the intro. If you skip the intro via ASM, the default name is left as 0s aka blank.

Setting a static name to the player

Well, this is beyond simple, lol. I'll keep my post the same format though, because first post :3

How to insert:

Before you begin to insert the routine, there are a few steps. Firstly player names are limited to 8 characters with the eighth character = 0xFF.
Convert the static name you want from ascii to hex. For OP, he wanted Jesse and James which convert into:
C4 D9 E7 E7 D9 FF FF FF - Jesse
C4 D5 E1 D9 E7 FF FF FF -James
Note that if all eight bytes don't get used, you should pad them with "FF" in your hex editor.
Now insert the 8 byte names into some free space in your ROM via hex editor and write down the pointers.

Now copy the following routine into a text editor:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r2, lr}
	ldr r0, .Name
	ldr r0, [r0]
	add r1, r0, #0x1
	ldrb r1, [r1]
	cmp r1, #0x1 @girl
	beq Girl
	ldr r1, .CustomNameBoy
	ldr r2, [r1]
	add r1, r1, #0x4
	ldr r1, [r1]
	str r2, [r0]
	add r0, r0, #0x4
	str r1, [r0]
	pop {r0-r2, pc}

Girl:
	ldr r1, .CustomNameGirl
	ldr r2, [r1]
	add r1, r1, #0x4
	ldr r1, [r1]
	str r2, [r0]
	add r0, r0, #0x4
	str r1, [r0]
	pop {r0-r2, pc}


.align 2
.Name:
	.word 0x300500C

.CustomNameBoy:
	.word 0x@pointer to boy name

.CustomNameGirl:
	.word 0x@pointer to girl name

You'll notice that I have the lines:

.CustomNameBoy:
	.word 0x@pointer to boy name

.CustomNameGirl:
	.word 0x@pointer to girl name

Change the 0x@pointer text to 0x[offset you inserted]. No need to add one.
After you've done that compile and insert into free space.

Usage:
You must callasm to the routine, and depending on the Player's gender it will set their name. To have their name inserted before the player starts playing the game, create a level script which calls this routine. If you don't know how, ask in a relevant thread (not here).

@FBI: 1) any way to pull up the naming routine for the player after the intro has been skipped so that players can name themselves later in the game? 2) can this be done for emerald? I have the research here that allows you to skip the birch intro if that helps with a starting point: https://www.pokecommunity.com/showpost.php?p=8444249&postcount=590

Spoiler:

He says I can post it, so I will now :)


Hi, this is a matter of tracking the routine that does the saving and calling it. While I don't know where it is, perhaps you can track it down if I tell you that the routine called when you hit save in the start menu is 0x6F4E8. Happy hacking!


That's the plan, if you have any routines which you would like to see, feel free to request them here.

Swapping between two possible start menus

Basically this routine will allow the player to have two different start menus. The start menu shown is dependent on a flag being set. The second one will not have a "Save" option.

How to insert:

Compile and insert into free space the following routine:

Spoiler:

.text
.align 2
.thumb
.thumb_func
main:
	mov r0, #0x94 @flag 0x250 divided by 4 (change if you want)
	lsl r0, #0x2
	ldr r1, =(0x806E6D0 +1)
	bl linker
	cmp r0, #0x0
	bne showMine

end:
	mov r0, #0x1
	ldr r1, =(0x806ED70 +1)
	bx r1
 
showMine:
	mov r0, #0x82
	lsl r0, r0, #0x4
	add r0, r0, #0x9
	ldr r1, =(0x806E6D0 +1)
	bl linker
	cmp r0, #0x0
	beq noDex
	mov r0, #0x0
	ldr r1, =(0x806ED94 +1)
	bl linker

noDex:
	mov r0, #0x82
	lsl r0, r0, #0x4
	add r0, r0, #0x8
	ldr r1, =(0x806E6D0 +1)
	bl linker
	cmp r0, #0x0
	beq noMon
	mov r0, #0x1
	ldr r1, =(0x806ED94 +1)
	bl linker

noMon:
	mov r0, #0x2
	ldr r1, =(0x806ED94 +1)
	bl linker
	mov r0, #0x3
	ldr r1, =(0x806ED94 +1)
	bl linker
	mov r0, #0x5
	ldr r1, =(0x806ED94 +1)
	bl linker
	mov r0, #0x6
	ldr r1, =(0x806ED94 +1)
	bl linker
	pop {r0}
	bx r0
 
linker2:
	bx r0
 
linker:
	bx r1

.align 2

Navigate to 0x6ED5C and insert the following byte changes:

00 48 00 47 XX XX XX 08

Where XX XX XX is the pointer (plus 1) in reverse hex to where you inserted the routine.
Navigate to 0x6EE42 and change 08 to 00.

Usage:
setflag 0x250 = show menu without save
clearflag 0x250 = show menu with save

That's it. It's toggled internally depending on the flag's state.

@FBI: this has been done by shinyquagsire for me before for emerald however I can not for the life of me figure out the magic he did. I do have previous commands associated to what he did if it helps, but if this could be done for emerald and also like how it was done, set a flag to give the player the battle frontier bag and allow me to clear flags and make the menu have certain things only (i.e. disabling the use of the bag) that'd be great. Here is the previous research: https://www.pokecommunity.com/showthread.php?p=8450458#post8450458

Spoiler:

checkitem hack to store quantity in 0x8008

This is probably a relatively esoteric hack, but I found a use for it so I might as well share it. When using the checkitem command, it will now buffer the quantity of said item into the variable 0x8008, and then behaves as usual for the regular usage of the command.

The reason I made this was to do something like the following dummy script:

checkitem ITEM_BLUESHARD 0x1
if B_< goto @none
buffernumber 0x0 0x8008
msgbox @string1 0x6
...

#org @string1
= You have [buffer1] Blue Shards.

It will always buffer to 0x8008, but you can change the RAM loc in the routine if you want it to be some other variable.

.thumb

@ 00 4A 10 47 XX+1 XX XX XX at 08099f88

lsl r0,r0,#0x10
lsr r0,r0,#0x10
ldr r2, =(0x020370C8) @ RAM location of 0x8008
strh r0, [r2]
ldr r2, =(0x08099f58+1)
cmp r0, r5
bcs branch
ldr r2, =(0x08099f90+1)

branch:
bx r2

@Spice: this is a great feature and I am wondering why it isn't a built-in command already. Anyways, I was wondering if you could translate this into emerald? There are always work arounds for this such as a flags for each item (which is a horrible way to go about it) but it'd be easier to just count them and that's be great.

~~~~

As usual, I'd be willing to donate to the cause and if either of you need motivation, I'm here to support you helping myself and others and that is why I'm willing to donate. Thanks for any help.

 

[Spherical Ice]

@Spice: this is a great feature and I am wondering why it isn't a built-in command already. Anyways, I was wondering if you could translate this into emerald? There are always work arounds for this such as a flags for each item (which is a horrible way to go about it) but it'd be easier to just count them and that's be great.

[EM] checkitem hack to store quantity in 0x8008

This is untested, but it should work based on the offsets I've changed. Let me know if something's up with it.

As usual, the dummy script should look something like this:

checkitem ITEM_BLUESHARD 0x1
if B_< goto @none
buffernumber 0x0 0x8008
msgbox @string1 0x6
...

#org @string1
= You have [buffer1] Blue Shards.

It will always buffer to 0x8008, but you can change the RAM loc in the routine if you want it to be some other variable.

.thumb

@ 00 4A 10 47 XX+1 XX XX XX at 080D6794

lsl r0,r0,#0x10
lsr r0,r0,#0x10
ldr r2, =(0x020375E8) @ RAM location of 0x8008 (I think)
strh r0, [r2]
ldr r2, =(0x080D6764+1)
cmp r0, r5
bcs branch
ldr r2, =(0x080D6778+1)

branch:
bx r2